mirror of
https://github.com/material-components/material-components-android.git
synced 2026-02-20 08:39:55 +08:00
06b88e84ad
The implementation in ics/ was the only remaining implementation of that class, so it made sense to move it directly into src/. Most of the implementations in base/ were the only remaining implementations, and thus also made sense to move into src/. The remaining classes were already post-fixed with Lollipop, so I see very little value in maintaining separate source directories for them (and I know these separate directories have also been flagged as confusing). They've all been moved into src/ as well now. I also renamed FloatingActionButtonLollipop to FloatingActionButtonImplLollipop here, as that better describes what it is a version of. PiperOrigin-RevId: 158187999
72 lines
2.1 KiB
Groovy
72 lines
2.1 KiB
Groovy
apply plugin: 'com.android.library'
|
|
|
|
archivesBaseName = 'design'
|
|
|
|
dependencies {
|
|
compile 'com.android.support:appcompat-v7:25.3.1'
|
|
compile 'com.android.support:recyclerview-v7:25.3.1'
|
|
compile 'com.android.support:support-annotations:25.3.1'
|
|
compile 'com.android.support:support-compat:25.3.1'
|
|
compile 'com.android.support:support-core-utils:25.3.1'
|
|
compile 'com.android.support:support-core-ui:25.3.1'
|
|
compile 'com.android.support:support-fragment:25.3.1'
|
|
compile 'com.android.support:transition:25.3.1'
|
|
|
|
testCompile ("com.android.support.test:runner:${project.rootProject.ext.testRunnerVersion}") {
|
|
exclude module: 'support-annotations'
|
|
}
|
|
testCompile 'junit:junit:4.12'
|
|
}
|
|
|
|
android {
|
|
sourceSets {
|
|
main.manifest.srcFile 'AndroidManifest.xml'
|
|
main.java.srcDir 'src'
|
|
main.res.srcDirs = [
|
|
'res',
|
|
'res-public'
|
|
]
|
|
main.assets.srcDir 'assets'
|
|
main.resources.srcDir 'src'
|
|
|
|
test.java.srcDir 'jvmtests/javatests'
|
|
}
|
|
|
|
buildTypes.all {
|
|
consumerProguardFiles 'proguard-rules.pro'
|
|
}
|
|
}
|
|
|
|
android.libraryVariants.all { variant ->
|
|
def name = variant.buildType.name
|
|
|
|
if (name.equals(com.android.builder.core.BuilderConstants.DEBUG)) {
|
|
return; // Skip debug builds.
|
|
}
|
|
def suffix = name.capitalize()
|
|
|
|
def jarTask = project.tasks.create(name: "jar${suffix}", type: Jar){
|
|
dependsOn variant.javaCompile
|
|
from variant.javaCompile.destinationDir
|
|
from 'LICENSE.txt'
|
|
}
|
|
def javadocTask = project.tasks.create(name: "javadoc${suffix}", type: Javadoc) {
|
|
source android.sourceSets.main.java
|
|
classpath = files(variant.javaCompile.classpath.files) + files(
|
|
"${android.sdkDirectory}/platforms/${android.compileSdkVersion}/android.jar")
|
|
}
|
|
|
|
def javadocJarTask = project.tasks.create(name: "javadocJar${suffix}", type: Jar) {
|
|
classifier = 'javadoc'
|
|
from 'build/docs/javadoc'
|
|
}
|
|
|
|
def sourcesJarTask = project.tasks.create(name: "sourceJar${suffix}", type: Jar) {
|
|
classifier = 'sources'
|
|
from android.sourceSets.main.java.srcDirs
|
|
}
|
|
|
|
artifacts.add('archives', javadocJarTask);
|
|
artifacts.add('archives', sourcesJarTask);
|
|
}
|